The StarDesktop

When working with documents, two services are used most frequently:

The com.sun.star.frame.Desktop service, which is similar to the core service of OpenOffice.org. It provides the functions for the frame object of OpenOffice.org, under which all document windows are classified. Documents can also be created, opened and imported using this service.
The basic functionality for the individual document objects is provided by the com.sun.star.document.OfficeDocument service. This provides the methods for saving, exporting and printing documents.

The com.sun.star.frame.Desktop service is created automatically when OpenOffice.org is started. This service can be addressed in OpenOffice.org Basic using the global name StarDesktop.

The most important interface of the StarDesktop is com.sun.star.frame.XComponentLoader. This basically covers the loadComponentFromURL method, which is responsible for creating, importing, and opening documents.

StarOffice 5 : The name of the StarDesktop object dates back to StarOffice 5, in which all document windows were embedded in one common application called StarDesktop. In the present version of OpenOffice.org, a visible StarDesktop is no longer used. The name StarDesktop was, however, retained for the frame object of OpenOffice.org because it clearly indicates that this is a basic object for the entire application.

The StarDesktop object replaces the Application object of StarOffice 5 which previously applied as a root object. However, unlike the old Application object, StarDesktop is primarily responsible for opening new documents. The functions resident in the old Application object for controlling the on-screen depiction of OpenOffice.org (for example, FullScreen, FunctionBarVisible, Height, Width, Top, Visible) are no longer used.

VBA : Whereas the active document in Word is accessed through Application.ActiveDocument and in Excel through Application.ActiveWorkbook, in OpenOffice.org, the StarDesktop is responsible for this task. The active document object is accessed in OpenOffice.org through the StarDesktop.CurrentComponent property, or through ThisComponent.

ThisComponent

The global name ThisComponent generally returns the same object as StarDesktop.CurrentComponent, with one significant advantage. If you are running from within the Basic IDE, debugging or exploring, then StarDesktop returns the Basic IDE itself. This is probably not what you want. ThisComponent returns the last previously active document.

Basic Information about Documents in OpenOffice.org

When working with OpenOffice.org documents, it is useful to deal with some of the basic issues of document administration in OpenOffice.org. This includes the way in which file names are structured for OpenOffice.org documents, as well as the format in which files are saved.

File Names in URL Notation

Since OpenOffice.org is a platform-independent application, it uses URL notation (which is independent of any operating system), as defined in the Internet Standard RFC 1738 for file names. Standard file names using this system begin with the prefix file:/// followed by the local path. If the file name contains sub-directories, then these are separated by a single forward slash, not with a backslash usually used under Windows. The following path references the test.odt file in the doc directory on the C: drive.

file:///C:/doc/test.odt

To convert local file names into an URL, OpenOffice.org provides the ConvertToUrl function. To convert a URL into a local file name, OpenOffice.org provides the ConvertFromUrl function:

MsgBox ConvertToUrl("C:\doc\test.odt") 
  ' supplies file:///C:/doc/test.odt
MsgBox ConvertFromUrl("file:///C:/doc/test.odt")    
  '  supplies (under Windows) c:\doc\test.odt

The example converts a local file name into a URL and displays it in a message box. It then converts a URL into a local file name and also displays this.

The Internet Standard RFC 1738, upon which this is based, permits use of the 0-9, a-z, and A-Z characters. All other characters are inserted as escape coding in the URLs. To do this, they are converted into their hexadecimal value in the UTF-8 set of characters and are preceded by a percent sign. A space in a local file name therefore, for example, becomes a %20 in the URL.

XML File Format

OpenOffice.org documents are based on the XML file format. XML-based files can be opened and edited with other programs.

Compression of Files

Since XML is based on standard text files, the resultant files are usually very large. OpenOffice.org therefore compresses the files and saves them as a ZIP file. By means of a storeAsURL method option, the user can save the original XML files directly. See storeAsURL Method Options, below.

Creating, Opening and Importing Documents

Documents are opened, imported and created using the method

StarDesktop.loadComponentFromURL(URL, Frame, SearchFlags, FileProperties)

The first parameter of loadComponentFromURL specifies the URL of the associated file.

As the second parameter, loadComponentFromURL expects a name for the frame object of the window that OpenOffice.org creates internally for its administration. The predefined _blank name is usually specified here, and this ensures that OpenOffice.org creates a new window.

Using these parameters, the user can open a OpenOffice.org document, since place holders (dummy values) can be assigned to the last two parameters:

Dim Doc As Object
Dim Url As String
Dim Dummy() 'An (empty) array of PropertyValues

Url = "file:///C:/test.odt"

Doc = StarDesktop.loadComponentFromURL(Url, "_blank", 0, Dummy)

The preceding call opens the test.odt file and displays this in a new window.

Any number of documents can be opened in this way in OpenOffice.org Basic and then edited using the returned document objects.

StarOffice 5 : StarDesktop.loadComponentFromURL supersedes the Documents.Add and Documents.Open methods from the old OpenOffice.org API.

Replacing the Content of the Document Window

The named _blank value for the Frame parameter ensures that OpenOffice.org creates a new window for every call from loadComponentFromURL. In some situations, it is useful to replace the content of an existing window. In this case, the frame object of the window should contain an explicit name. Note that this name must not begin with an underscore. Furthermore, the SearchFlags parameter must be set so that the corresponding framework is created, if it does not already exist. The corresponding constant for SearchFlags is:

SearchFlags = com.sun.star.frame.FrameSearchFlag.CREATE + _
              com.sun.star.frame.FrameSearchFlag.ALL

The following example shows how the content of an opened window can be replaced with the help of the frame parameter and SearchFlags:

Dim Doc As Object
Dim Dummy() 
Dim Url As String
Dim SearchFlags As Long
 
SearchFlags = com.sun.star.frame.FrameSearchFlag.CREATE + _
              com.sun.star.frame.FrameSearchFlag.ALL
Url = "file:///C:/test.odt"
Doc = StarDesktop.loadComponentFromURL(Url, "MyFrame", SearchFlags, Dummy)
MsgBox "Press OK to display the second document."

Url = "file:///C:/test2.odt"
Doc = StarDesktop.loadComponentFromURL(Url, "MyFrame", _
      SearchFlags, Dummy)

The example first opens the test.odt file in a new window with the frame name of MyFrame. Once the message box has been confirmed, it replaces the content of the window with the test2.odt file.

loadComponentFromURL Method Options

The fourth parameter of the loadComponentFromURL function is a PropertyValue data field. which provides OpenOffice.org with various options for opening and creating documents. The data field must provide a PropertyValue structure for each option in which the name of the option is saved as a string as well as the associated value.

loadComponentFromURL supports the following options:

AsTemplate (Boolean): if true, loads a new, untitled document from the given URL. If is false, template files are loaded for editing.
CharacterSet (String): defines which set of characters a document is based on.
FilterName (String): specifies a special filter for the loadComponentFromURL function. The filter names available are defined in the \share\config\registry\instance\org\openoffice\office\TypeDetection.xml file.
FilterData (String): defines additional options for filters.
FilterOptions (String): defines additional options (used by old filters).
Hidden (Boolean): value true loads the document in invisible mode.
JumpMark (String): once a document has been opened, jumps to the position defined in JumpMark.
MacroExecutionMode (Integer): indicates if document macros may be executed. Values : see com.sun.star.document.MacroExecMode
Password (String): transfers a password for a protected file.
ReadOnly (Boolean): value true loads a document in read-only mode.
UpdateDocMode (Integer): indicates how/if links will be updated. Values : see com.sun.star.document.UpdateDocMode

The following example shows how a text file separated by a comma in OpenOffice.org Calc can be opened using the FilterName option.

Dim Doc As Object
Dim FileProperties(1) As New com.sun.star.beans.PropertyValue
Dim Url As String

Url = "file:///C:/doc.csv"
FileProperties(0).Name = "FilterName"
FileProperties(0).Value ="Text - txt - csv (StarCalc)"
FileProperties(1).Name = "FilterOptions"
FileProperties(1).value  = "44,34,0,1"

Doc = StarDesktop.loadComponentFromURL(Url, "_blank", 0, FileProperties())

The FileProperties array has two elements, one for each option used. The Filtername property defines whether OpenOffice.org uses a OpenOffice.org Calc text filter to open files. The FilterOptions property contains the description of the syntax of the csv file.

Creating New Documents

OpenOffice.org automatically creates a new document if the document specified in the URL is a template.

Alternatively, if only an empty document without any adaptation is needed, a private:factory URL can be specified:

Dim Dummy() 
Dim Url As String
Dim Doc As Object

Url = "private:factory/swriter"
Doc = StarDesktop.loadComponentFromURL(Url, "_blank", 0, Dummy())

The call creates an empty OpenOffice.org writer document.

Document Objects

The loadComponentFromURL function introduced in the previous section returns a document object. This supports the com.sun.star.document.OfficeDocument service, which in turn provides two central interfaces:

The com.sun.star.frame.XStorable interface, which is responsible for saving documents.
The com.sun.star.view.XPrintable interface, which contains the methods for printing documents.

Saving and Exporting Documents

OpenOffice.org documents are saved directly through the document object. The store method of the com.sun.star.frame.XStorable interface is available for this purpose:

Doc.store()

This call functions provided that the document has already been assigned a memory space. This is not the case for new documents. In this instance, the storeAsURL method is used. This method is also defined in com.sun.star.frame.XStorable and can be used to define the location of the document:

Dim URL As String
Dim Dummy()

Url = "file:///C:/test3.odt"
Doc.storeAsURL(URL, Dummy())

In addition to the preceding methods, com.sun.star.frame.XStorable also provides some help methods which are useful when saving documents. These are:

hasLocation(): specifies whether the document has already been assigned a URL.
isReadonly(): specifies whether a document has read-only protection.
isModified(): specifies whether a document has been modified since it was last saved.

The code for saving a document can be extended by these options so that the document is only saved if the object has actually been modified and the file name is only queried if it is actually needed:

If (Doc.isModified) Then
  If (Doc.hasLocation And (Not Doc.isReadOnly)) Then
    Doc.store()
  Else
    Doc.storeAsURL(URL, Dummy())
  End If
End If

The example first checks whether the relevant document has been modified since it was last saved. It only continues with the saving process if this is the case. If the document has already been assigned a URL and is not a read-only document, it is saved under the existing URL. If it does not have a URL or was opened in its read-only status, it is saved under a new URL.

storeAsURL Method Options

As with the loadComponentFromURL method, some options can also be specified in the form of a PropertyValue data field using the storeAsURL method. These determine the procedure OpenOffice.org uses when saving a document. storeAsURL provides the following options:

CharacterSet (String): defines which set of characters a document is based on.
FilterName (String): specifies a special filter for the loadComponentFromURL function. The filter names available are defined in the \share\config\registry\instance\org\openoffice\office\TypeDetection.xml file.
FilterData (String): defines additional options for filters.
FilterOptions (String): defines additional options (used by old filters).
Overwrite (Boolean): allows a file which already exists to be overwritten without a query.
Password (String): transfers the password for a protected file.
Unpacked (Boolean): saves the document (not compressed) in sub-directories.; The possibility to store documents in unpacked way is not currently supported, the "Unpacked" property is just ignored, see Issue 64364 .

The following example shows how the Overwrite option can be used in conjunction with storeAsURL:

Dim Doc As Object
Dim FileProperties(0) As New com.sun.star.beans.PropertyValue
Dim Url As String
' ... Initialize Doc 

Url = "file:///c:/test3.odt"
FileProperties(0).Name = "Overwrite"
FileProperties(0).Value = True
Doc.storeAsURL(Url, FileProperties())

The example then saves Doc under the specified file name if a file already exists under the name.

Printing Documents

Similar to saving, documents are printed out directly by means of the document object. The Print method of the com.sun.star.view.Xprintable interface is provided for this purpose. In its simplest form, the print call is:

Dim Dummy()

Doc.print(Dummy())

As in the case of the loadComponentFromURL method, the Dummy parameter is a PropertyValue data field through which OpenOffice.org can specify several options for printing.

The options of the print method

The print method expects a PropertyValue data field as a parameter, which reflects the settings of the print dialog of OpenOffice.org:

CopyCount (Integer): specifies the number of copies to be printed.
FileName (String): prints the document in the specified file.
Collate (Boolean): advises the printer to collate the pages of the copies.
Sort (Boolean): sorts the pages when printing out several copies (CopyCount > 1).
Pages (String): contains the list of the pages to be printed (syntax as specified in print dialog).
Wait (Boolean): if set to True the print method will return after the job is stored on the waiting list for the printer. Use this option if you want to close the document after print.

The following example shows how several pages of a document can be printed out using the Pages option:

Dim Doc As Object
Dim PrintProperties(1) As New com.sun.star.beans.PropertyValue

PrintProperties(0).Name="Pages"
PrintProperties(0).Value="1-3; 7; 9"
PrintProperties(1).Name="Wait"
PrintProperties(1).Value=True
Doc.print(PrintProperties())

Printer selection and settings

The com.sun.star.view.XPrintable interface provides the Printer property, which selects the printer. This property receives a PropertyValue data field with the following settings:

Name (String): specifies the name of printer.
PaperOrientation (Enum): specifies the paper orientation (com.sun.star.view.PaperOrientation.PORTRAIT value for portrait format, com.sun.star.view.PaperOrientation.LANDSCAPE for landscape format).
PaperFormat (Enum): specifies the paper format (for example, com.sun.star.view.PaperFormat.A4 for DIN A4 or com.sun.star.view.PaperFormat.Letter for US letters).
PaperSize (Size): specifies the paper size in hundredths of a millimeter.

The following example shows how a printer can be changed and the paper size set with the help of the Printer property.

Dim Doc As Object
Dim PrinterProperties(1) As New com.sun.star.beans.PropertyValue
Dim PaperSize As New com.sun.star.awt.Size

PaperSize.Width = 20000   ' corresponds to 20 cm
PaperSize.Height = 20000   ' corresponds to 20 cm
PrinterProperties (0).Name="Name"
PrinterProperties (0).Value="My HP Laserjet"
PrinterProperties (1).Name="PaperSize"
PrinterProperties (1).Value=PaperSize
Doc.Printer = PrinterProperties()

The example defines an object named PaperSize with the com.sun.star.awt.Size type. This is needed to specify the paper size. Furthermore, it creates a data field for two PropertyValue entries named PrinterProperties. This data field is then initialized with the values to be set and assigned the Printer property. From the standpoint of UNO, the printer is not a real property but an imitated one. fr:FR/Documentation/BASIC Guide/StarDesktop hu:HU/Documentation/BASIC Guide/StarDesktop it:IT/Documentation/BASIC Guide/StarDesktop ja:JA/Documentation/BASIC Guide/StarDesktop zh:ZH/Documentation/BASIC Guide/StarDesktop

Content on this page is licensed under the Public Documentation License (PDL).