Sancho: Основной текст

2011-09-05T16:03:19Z

Основной текст

New page

<section begin=title /><noinclude>{{DISPLAYTITLE:</noinclude>The Structure of Charts<noinclude>}}</noinclude><section end=title />{{BreadCrumbL10n}}

{{Documentation/BASICGuideTOC
|ShowPrevNext=block
|ShowPrevPage=block
|PrevPage=EN/documentation/basic_guide/charts_in_spreadsheets
|NextPage=EN/documentation/basic_guide/chart_types
|chart=block
}}

__NOTOC__

The structure of a chart, and therefore the list of services and interfaces supported by it, depends on the chart type. For example, the methods and properties of the Z-axis, are available in 3D charts, but not in 2D charts, and in pie charts, there are no interfaces for working with axes.

== Title, Subtitle and Legend ==

Title, subtitle and legend are basic elements provided for every chart. The <tt>Chart</tt> object provides the following properties for administrating these elements:

;<tt>HasMainTitle (Boolean)</tt>:activates the title
;<tt>Title (Object)</tt>:object with detailed information about the chart title (supports the <idl>com.sun.star.chart.ChartTitle</idl> service)
;<tt>HasSubTitle(Boolean)</tt>:activates the subtitle
;<tt>Subtitle (Object)</tt>:object with detailed information about the chart subtitle (supports the <idl>com.sun.star.chart.ChartTitle</idl> service)
;<tt>HasLegend (Boolean)</tt>:activates the legend
;<tt>Legend (Object)</tt>:object with detailed information about the legend (supports the <idl>com.sun.star.chart.ChartLegend</idl> service)

Both services <tt>com.sun.star.chart.ChartTitle</tt> and <tt>com.sun.star.chart.ChartLegend</tt> do support the service <tt>com.sun.star.drawing.Shape</tt>. This allows to determine the position and size of the elements using the <tt>Position</tt> and <tt>Size</tt> properties. As the size of the legend and the titles is calculated automatically based on the current content and the character height for example, the size property provides read access only.

Fill and line properties (<idl>com.sun.star.drawing.FillProperties</idl> and <idl>com.sun.star.drawing.LineProperties</idl> services) as well as the character properties (<idl>com.sun.star.style.CharacterProperties</idl> service) are provided for further formatting of the elements.

<idl>com.sun.star.chart.ChartTitle</idl> contains not only the listed formatting properties, but also two other properties:

;<tt>String (String)</tt>:text which to be displayed as the title or subtitle
;<tt>TextRotation (Long)</tt>:angle of rotation of text in 100ths of a degree

The legend (<idl>com.sun.star.chart.ChartLegend</idl>) contains the following additional property:

;<tt>Alignment (Enum)</tt>:position at which the legend appears (value of type <idl>com.sun.star.chart.ChartLegendPosition</idl>)

The following example creates a chart with a title "Main Title String", a subtitle "Subtitle String" and a legend. The legend has a gray background color, is placed at the bottom of the chart, and has a character size of 7 points.

<source lang="oobas">
Dim Doc As Object
Dim Charts As Object
Dim Chart as Object
Dim Rect As New com.sun.star.awt.Rectangle
Dim RangeAddress(0) As New com.sun.star.table.CellRangeAddress

Rect.X = 8000
Rect.Y = 1000
Rect.Width = 10000
Rect.Height = 7000
RangeAddress(0).Sheet = 0
RangeAddress(0).StartColumn = 0
RangeAddress(0).StartRow = 0
RangeAddress(0).EndColumn = 2
RangeAddress(0).EndRow = 12

Doc = ThisComponent

Charts = Doc.Sheets(0).Charts
Charts.addNewByName("MyChart", Rect, RangeAddress(), True, True)
Chart = Charts.getByName("MyChart").EmbeddedObject
Chart.HasMainTitle = True
Chart.Title.String = "Main Title String"
Chart.HasSubTitle = True
Chart.Subtitle.String = "Subtitle String"
Chart.HasLegend = True
Chart.Legend.Alignment = com.sun.star.chart.ChartLegendPosition.BOTTOM
Chart.Legend.FillStyle = com.sun.star.drawing.FillStyle.SOLID
Chart.Legend.FillColor = RGB(210, 210, 210)
Chart.Legend.CharHeight = 7
</source>

== Background ==

Every chart has a background area. The <tt>Chart</tt> object provides the property <tt>Area</tt> to format the background:

;<tt>Area (Object)</tt>:background area of the chart (supports <idl>com.sun.star.chart.ChartArea</idl> service)

The background of a chart covers its complete area, including the area under the title, subtitle and legend. The associated <idl>com.sun.star.chart.ChartArea</idl> service supports line and fill properties.

== Diagram ==

The <tt>Chart</tt> object provides the property <tt>Diagram</tt> which forms the coordinate system with axes and grids, where the data finally is displayed:

;<tt>Diagram (Object)</tt>:object forming the coordinate system where the data is plotted. It supports <idl>com.sun.star.chart.Diagram</idl> service and:
:* <idl>com.sun.star.chart.StackableDiagram</idl>
:* <idl>com.sun.star.chart.ChartAxisXSupplier</idl>
:* <idl>com.sun.star.chart.ChartAxisYSupplier</idl>
:* <idl>com.sun.star.chart.ChartAxisZSupplier</idl>
:* <idl>com.sun.star.chart.ChartTwoAxisXSupplier</idl>
:* <idl>com.sun.star.chart.ChartTwoAxisYSupplier</idl>

Different services are supported depending on the chart type (see
[[Documentation/BASIC_Guide/Chart_Types|Chart Types]]).

== Wall and Floor ==

The chart wall is the background of the coordinate system where the data is plotted.
Two chart walls usually exist for 3D charts: one behind the plotted data and one as the left-hand or right-hand demarcation. This depends on the rotation of the chart. 3D charts usually also have a floor.

The <tt>Diagram</tt> object provides the properties Wall and Floor:

;<tt>Wall (Object)</tt>:background wall of the coordinate system (supports <idl>com.sun.star.chart.ChartArea</idl> service)
;<tt>Floor (Object)</tt>:floor panel of coordinate system (only for 3D charts, supports <idl>com.sun.star.chart.ChartArea</idl> service)

The specified objects support the <tt>com.sun.star.chart.ChartArea</tt> service, which provides the usual fill and line properties (<idl>com.sun.star.drawing.FillProperties</idl> and <idl>com.sun.star.drawing.LineProperties</idl> services, refer to [[Documentation/BASIC_Guide/Drawings_Presentations|Drawings and Presentations]]).

The following example shows how graphics (named Sky) already contained in {{OOo}} can be used as a background for a chart. The wall is set to be blue.

<source lang="oobas">
Dim Doc As Object
Dim Charts As Object
Dim Chart as Object
Dim Rect As New com.sun.star.awt.Rectangle
Dim RangeAddress(0) As New com.sun.star.table.CellRangeAddress

Rect.X = 8000
Rect.Y = 1000
Rect.Width = 10000
Rect.Height = 7000
RangeAddress(0).Sheet = 0
RangeAddress(0).StartColumn = 0
RangeAddress(0).StartRow = 0
RangeAddress(0).EndColumn = 2
RangeAddress(0).EndRow = 12

Doc = ThisComponent

Charts = Doc.Sheets(0).Charts
Charts.addNewByName("MyChart", Rect, RangeAddress(), True, True)
Chart = Charts.getByName("MyChart").EmbeddedObject
Chart.Area.FillStyle = com.sun.star.drawing.FillStyle.BITMAP
Chart.Area.FillBitmapName = "Sky"
Chart.Area.FillBitmapMode = com.sun.star.drawing.BitmapMode.REPEAT

Chart.Diagram.Wall.FillStyle = com.sun.star.drawing.FillStyle.SOLID
Chart.Diagram.Wall.FillColor = RGB(00,132,209)
</source>

== Axes ==

{{OOo}} recognizes five different axes that can be used in a chart. In the simplest scenario, these are the X and Y-axes. When working with 3D charts, a Z-axis is also sometimes provided. For charts in which the values of the various rows of data deviate significantly from one another, {{OOo}} provides a second X and Y-axis for second scaling operations.

The <tt>Diagram</tt> object provides the following properties to access the axes:

;<tt>HasXAxis (Boolean)</tt>:activates the X-axis
;<tt>XAxis (Object)</tt>:object with detailed information about the X-axis (supports <idl>com.sun.star.chart.ChartAxis</idl> service)
;<tt>HasXAxisDescription (Boolean)</tt>:activates the labels for the interval marks for the X-axis

;<tt>HasYAxis (Boolean)</tt>:activates the Y-axis
;<tt>YAxis (Object)</tt>:object with detailed information about the Y-axis (supports <idl>com.sun.star.chart.ChartAxis</idl> service)
;<tt>HasYAxisDescription (Boolean)</tt>:activates the labels for the interval marks for the Y-axis

;<tt>HasZAxis (Boolean)</tt>:activates the Z-axis
;<tt>ZAxis (Object)</tt>:object with detailed information about the Z-axis (supports <idl>com.sun.star.chart.ChartAxis</idl> service)
;<tt>HasZAxisDescription (Boolean)</tt>:activates the labels for the interval marks for the Z-axis

;<tt>HasSecondaryXAxis (Boolean)</tt>:activates the secondary X-axis
;<tt>SecondaryXAxis (Object)</tt>:object with detailed information about the secondary X-axis (supports <idl>com.sun.star.chart.ChartAxis</idl> service)
;<tt>HasSecondaryXAxisDescription (Boolean)</tt>:activates the labels for the interval marks for the secondary X-axis

;<tt>HasSecondaryYAxis (Boolean)</tt>:activates the secondary Y-axis
;<tt>SecondaryYAxis (Object)</tt>:object with detailed information about the secondary Y-axis (supports <idl>com.sun.star.chart.ChartAxis</idl> service)
;<tt>HasSecondaryYAxisDescription (Boolean)</tt>:activates the labels for the interval marks for the secondary Y-axis

== Properties of Axes ==

The axis objects of a {{OOo}} chart support the <idl>com.sun.star.chart.ChartAxis</idl> service. In addition to the properties for characters <idl>(com.sun.star.style.CharacterProperties</idl> service, refer to [[Documentation/BASIC_Guide/Text_Documents|Text Documents]]) and lines <idl>(com.sun.star.drawing.LineStyle</idl> service, refer to [[Documentation/BASIC_Guide/Drawings_Presentations|Drawings and Presentations]]), it provides the following properties:

===Scaling properties:===
;<tt>Max (Double)</tt>:maximum value for axis
;<tt>Min (Double)</tt>:minimum value for axis
;<tt>Origin (Double)</tt>:point of intersect for crossing axes
;<tt>StepMain (Double)</tt>:distance between the major interval marks
;<tt>StepHelp (Double)</tt>:distance between the minor interval marks (deprecated since OpenOffice.org 3.0; Use property StepHelpCount instead)
;<tt>StepHelpCount (Long)</tt>:Contains the number of minor intervals within a major interval. E.g. a StepHelpCount of 5 divides the major interval into 5 pieces and thus produces 4 minor tick marks. (available since OpenOffice.org 3.0)
;<tt>AutoMax (Boolean)</tt>:the maximum value for the axis is calculated automatically when set to true
;<tt>AutoMin (Boolean)</tt>:the minimum value for the axis is calculated automatically when set to true
;<tt>AutoOrigin (Boolean)</tt>:the origin is determined automatically when set to true
;<tt>AutoStepMain (Boolean)</tt>:StepMain is determined automatically when set to true
;<tt>AutoStepHelp (Boolean)</tt>:StepHelpCount is determined automatically when set to true
;<tt>Logarithmic (Boolean)</tt>:scales the axes in logarithmic manner (rather than linear)
;<tt>ReverseDirection (Boolean)</tt>:determines if the axis orientation is mathematical or reversed. (available since OpenOffice.org 2.4)

===Label properties:===
;<tt>DisplayLabels (Boolean)</tt>:activates the text label at the interval marks
;<tt>TextRotation (Long)</tt>:angle of rotation of text label in 100ths of a degree
;<tt>ArrangeOrder (enum)</tt>:the label may be staggered, thus they are positioned alternately over two lines (values according to <idl>com.sun.star.chart.ChartAxisArrangeOrderType</idl>)
;<tt>TextBreak (Boolean)</tt>:permits line breaks within the axes labels
;<tt>TextCanOverlap (Boolean)</tt>:permits an overlap of the axes labels
;<tt>NumberFormat (Long)</tt>:number format to be used with the axes labels
;<tt>LinkNumberFormatToSource (Boolean)</tt>:determines whether to use the number format given by the container document, or from the property <tt>NumberFormat</tt>. (since OpenOffice.org 2.3)

===Interval mark properties:===
;<tt>Marks (Const)</tt>:determines the position of the major interval marks (values in accordance with <idl>com.sun.star.chart.ChartAxisMarks</idl>)
;<tt>HelpMarks (Const)</tt>:determines the position of the minor interval marks (values in accordance with <idl>com.sun.star.chart.ChartAxisMarks</idl>)

===Only for bar charts:===
;<tt>Overlap (Long)</tt>:percentage which specifies the extent to which the bars of different sets of data may overlap (at 100%, the bars are shown as completely overlapping, at -100%, there is a distance of the width of one bar between them)
;<tt>GapWidth (long)</tt>:percentage which specifies the distance there may be between the different groups of bars of a chart (at 100%, there is a distance corresponding to the width of one bar)

== Grids ==

For the primary axes grids and sub grids can be displayed, matching to the major and minor intervals.
The <tt>Diagram</tt> object provides the following properties to access the grids:

;<tt>HasXAxisGrid (Boolean)</tt>:activates major grid for X-axis
;<tt>XMainGrid (Object)</tt>:object with detailed information about the major grid for X-axis (supports <idl>com.sun.star.chart.ChartGrid</idl> service)
;<tt>HasXAxisHelpGrid (Boolean)</tt>:activates minor grid for X-axis
;<tt>XHelpGrid (Object)</tt>:object with detailed information about the minor grid for X-axis (supports <idl>com.sun.star.chart.ChartGrid</idl> service)

the same for y and z:

;<tt>HasYAxisGrid (Boolean)</tt>:activates major grid for Y-axis
;<tt>YMainGrid (Object)</tt>:object with detailed information about the major grid for Y-axis (supports <idl>com.sun.star.chart.ChartGrid</idl> service)
;<tt>HasYAxisHelpGrid (Boolean)</tt>:activates minor grid for Y-axis
;<tt>YHelpGrid (Object)</tt>:object with detailed information about the minor grid for Y-axis (supports <idl>com.sun.star.chart.ChartGrid</idl> service)

;<tt>HasZAxisGrid (Boolean)</tt>:activates major grid for Z-axis
;<tt>ZMainGrid (Object)</tt>:object with detailed information about the major grid for Z-axis (supports <idl>com.sun.star.chart.ChartGrid</idl> service)
;<tt>HasZAxisHelpGrid (Boolean)</tt>:activates minor grid for Z-axis
;<tt>ZHelpGrid (Object)</tt>:object with detailed information about the minor grid for Z-axis (supports <idl>com.sun.star.chart.ChartGrid</idl> service)

The grid object is based on the <idl>com.sun.star.chart.ChartGrid</idl> service, which in turn supports the line properties of the <idl>com.sun.star.drawing.LineStyle</idl> support service (refer to [[Documentation/BASIC_Guide/Drawings_Presentations|Drawings and Presentations]]).

== Axes Title ==

For all axes an additional title can be displayed.
The <tt>Diagram</tt> object provides the following properties to access the axes title:

;<tt>HasXAxisTitle (Boolean)</tt>:activates title of X-axis
;<tt>XAxisTitle (Object)</tt>:object with detailed information about title of the X-axis (supports <idl>com.sun.star.chart.ChartTitle</idl> service)

same y and z:

;<tt>HasYAxisTitle (Boolean)</tt>:activates title of Y-axis
;<tt>YAxisTitle (Object)</tt>:object with detailed information about title of the Y-axis (supports <idl>com.sun.star.chart.ChartTitle</idl> service)

;<tt>HasZAxisTitle (Boolean)</tt>:activates title of Z-axis
;<tt>ZAxisTitle (Object)</tt>:object with detailed information about title of the Z-axis (supports <idl>com.sun.star.chart.ChartTitle</idl> service)

and for the secondary axes (available since OpenOffice.org 3.0):

;<tt>HasSecondaryXAxisTitle (Boolean)</tt>:activates title of the secondary X-axis.
;<tt>SecondXAxisTitle (Object)</tt>:object with detailed information about title of the secondary X-axis (supports <idl>com.sun.star.chart.ChartTitle</idl> service)

;<tt>HasSecondaryYAxisTitle (Boolean)</tt>:activates title of the secondary Y-axis.
;<tt>SecondYAxisTitle (Object)</tt>:object with detailed information about title of the secondary Y-axis (supports <idl>com.sun.star.chart.ChartTitle</idl> service)

The objects for formatting the axes title are based on the <idl>com.sun.star.chart.ChartTitle</idl> service, which is also used for chart titles.

=== Example ===

The following example creates a line chart. The color for the rear wall of the chart is set to white. Both the X and Y-axes have a gray grid for visual orientation. The minimum value of the Y-axis is fixed to 0 and the maximum value is fixed to 100 so that the resolution of the chart is retained even if the values are changed. The X-axis points in reverse direction from right to left. And a title for the X-axis was added.

<source lang="oobas">
Dim Doc As Object
Dim Charts As Object
Dim Chart as Object
Dim Rect As New com.sun.star.awt.Rectangle
Dim RangeAddress(0) As New com.sun.star.table.CellRangeAddress

Doc = ThisComponent
Charts = Doc.Sheets(0).Charts

Rect.X = 8000
Rect.Y = 1000
Rect.Width = 10000
Rect.Height = 7000
RangeAddress(0).Sheet = 0
RangeAddress(0).StartColumn = 0
RangeAddress(0).StartRow = 0
RangeAddress(0).EndColumn = 2
RangeAddress(0).EndRow = 12

Charts.addNewByName("MyChart", Rect, RangeAddress(), True, True)
Chart = Charts.getByName("MyChart").embeddedObject
Chart.Diagram = Chart.createInstance("com.sun.star.chart.LineDiagram")
Chart.Diagram.Wall.FillColor = RGB(255, 255, 255)
Chart.Diagram.HasXAxisGrid = True
Chart.Diagram.XMainGrid.LineColor = RGB(192, 192, 192)
Chart.Diagram.HasYAxisGrid = True
Chart.Diagram.YMainGrid.LineColor = RGB(192, 192, 192)
Chart.Diagram.YAxis.Min = 0
Chart.Diagram.YAxis.Max = 100

Chart.Diagram.XAxis.ReverseDirection = true 'needs OpenOffice.org 2.4 or newer
Chart.Diagram.HasXAxisTitle = true
Chart.Diagram.XAxisTitle.String = "Reversed X Axis Example"
</source>

== 3D Charts ==

Most charts in {{OOo}} can also be displayed with 3D graphics. The following properties are provided for 3D charts at the <tt>Diagram</tt> object:

;<tt>Dim3D (Boolean)</tt>:activates 3D display
;<tt>Deep (Boolean)</tt>:the series will be arranged behind each other in z-direction
;<tt>RightAngledAxes (Boolean)</tt>:activates a 3D display mode where X- and Y-axes form a right angle within the projection. (available since OpenOffice.org 2.3)
;<tt>D3DScenePerspective (Enum)</tt>:defines whether the 3D objects are to be drawn in perspective or parallel projection.(values according to <idl>com.sun.star.drawing.ProjectionMode</idl>)
;<tt>Perspective (Long)</tt>:Perspective of 3D charts ( [0,100] ) (available since OpenOffice.org 2.4.1)
;<tt>RotationHorizontal (Long)</tt>:Horizontal rotation of 3D charts in degrees ( [-180,180] ) (available since OpenOffice.org 2.4.1)
;<tt>RotationVertical (Long)</tt>:Vertical rotation of 3D charts in degrees ( [-180,180] ) (available since OpenOffice.org 2.4.1)

The following example creates a 3D area chart.

<source lang="oobas">
Dim Doc As Object
Dim Charts As Object
Dim Chart as Object
Dim Rect As New com.sun.star.awt.Rectangle
Dim RangeAddress(0) As New com.sun.star.table.CellRangeAddress

Doc = ThisComponent
Charts = Doc.Sheets(0).Charts

Rect.X = 8000
Rect.Y = 1000
Rect.Width = 10000
Rect.Height = 7000
RangeAddress(0).Sheet = 0
RangeAddress(0).StartColumn = 0
RangeAddress(0).StartRow = 0
RangeAddress(0).EndColumn = 2
RangeAddress(0).EndRow = 12

Charts.addNewByName("MyChart", Rect, RangeAddress(), True, True)
Chart = Charts.getByName("MyChart").embeddedObject
Chart.Diagram = Chart.createInstance("com.sun.star.chart.AreaDiagram")
Chart.Diagram.Dim3D = true
Chart.Diagram.Deep = true
Chart.Diagram.RightAngledAxes = true 'needs OpenOffice.org 2.3 or newer
Chart.Diagram.D3DScenePerspective = com.sun.star.drawing.ProjectionMode.PERSPECTIVE
Chart.Diagram.Perspective = 100 'needs OpenOffice.org 2.4.1 or newer
Chart.Diagram.RotationHorizontal = 60 'needs OpenOffice.org 2.4.1 or newer
Chart.Diagram.RotationVertical = 30 'needs OpenOffice.org 2.4.1 or newer
</source>

== Stacked Charts ==

Stacked charts are charts that are arranged with several individual values on top of one another to produce a total value. This view shows not only the individual values, but also an overview of all the values.

In {{OOo}}, various types of charts can be displayed in a stacked form. All of these charts support the <idl>com.sun.star.chart.StackableDiagram</idl> service, which in turn provides the following properties:

;<tt>Stacked (Boolean)</tt>:activates the stacked viewing mode
;<tt>Percent (Boolean)</tt>:rather than absolute values, displays their percentage distribution

{{PDL1}}

EN/documentation/basic guide/structure of charts - Revision history

Sancho: Основной текст