Sancho at 10:48, 6 September 2011

2011-09-06T10:48:06Z

Sancho at 16:50, 2 September 2011

2011-09-02T16:50:11Z

Sancho: moved EN/documentation/basic guide/strings (runtime library) to EN/documentation/basic guide/strings runtime library

2011-09-02T16:43:13Z

moved EN/documentation/basic guide/strings (runtime library) to EN/documentation/basic guide/strings runtime library

Sancho: Created page with "
{{DISPLAYTITLE:Strings ({{OOo}} BASIC Runtime Library)}}
{{BreadCrumbL10n}} {{Documentat..."

2011-09-01T16:09:06Z

Created page with "<section begin=title /><noinclude>{{DISPLAYTITLE:</noinclude>Strings ({{OOo}} BASIC Runtime Library)<noinclude>}}</noinclude><section end=title />{{BreadCrumbL10n}} {{Documentat..."

New page

<section begin=title /><noinclude>{{DISPLAYTITLE:</noinclude>Strings ({{OOo}} BASIC Runtime Library)<noinclude>}}</noinclude><section end=title />{{BreadCrumbL10n}}

{{Documentation/BASICGuideTOC
|ShowPrevNext=block
|ShowPrevPage=block
|PrevPage=EN/documentation/basic_guide/conversion_functions_(runtime_library)
|NextPage=EN/documentation/basic_guide/date_and_time_(runtime_library)
|runtime=block
}}

__NOTOC__

== Working with Sets of Characters ==

When administering strings, {{OOo}} Basic uses the set of Unicode characters. The <tt>Asc</tt> and <tt>Chr</tt> functions allow the Unicode value belonging to a character to be established and/or the corresponding character to be found for a Unicode value. The following expressions assign the various Unicode values to the code variable:

<source lang="oobas">
Code = Asc("A") ' Latin letter A (Unicode-value 65)
Code = Asc("€") ' Euro character (Unicode-value 8364)
Code = Asc("Л") ' Cyrillic letter Л (Unicode-value 1083)
</source>

Conversely, the expression

<source lang="oobas">
MyString = Chr(13)
</source>

ensures that the <tt>MyString</tt> string is initialized with the value of the number <tt>13</tt>, which stands for a hard line break.

The <tt>Chr</tt> command is often used in Basic languages to insert control characters in a string. The assignment

<source lang="oobas">
MyString = Chr(9) + "This is a test" + Chr(13)
</source>

therefore ensures that the text is preceded by a tab character (Unicode-value 9) and that a hard line break (Unicode-value 13) is added after the text.

== Accessing Parts of a String ==

{{OOo}} Basic provides three functions that return partial strings, plus a length function:

;<tt>Left(MyString, Length)</tt>:returns the first <tt>Length</tt> characters of <tt>MyString</tt>.
;<tt>Right(MyString, Length)</tt>:returns the last <tt>Length</tt> characters of <tt>MyString</tt>.
;<tt>Mid(MyString, Start, Length)</tt>:returns first <tt>Length</tt> characters of <tt>MyString</tt> as of the <tt>Start</tt> position.
;<tt>Len(MyString)</tt>:returns the number of characters in <tt>MyString</tt>.

Here are a few example calls for the named functions:

<source lang="oobas">
Dim MyString As String
Dim MyResult As String
Dim MyLen As Integer

MyString = "This is a small test"
MyResult = Left(MyString,5) ' Provides the string "This "
MyResult = Right(MyString, 5) ' Provides the string " test"
MyResult = Mid(MyString, 8, 5) ' Provides the string " a sm"
MyLen = Len(MyString) ' Provides the value 20
</source>

== Search and Replace ==

{{OOo}} Basic provides the <tt>InStr</tt> function for searching for a partial string within another string:

<source lang="oobas">
ResultString = InStr (MyString, SearchString)
</source>

The <tt>SearchString</tt> parameter specifies the string to be searched for within <tt>MyString</tt>. The function returns a number that contains the position at which the <tt>SearchString</tt> first appears within <tt>MyString</tt>; a return value of zero indicates no match. If you want to find other matches for the string, the function also provides the opportunity to specify an optional start position from which {{OOo}} Basic begins the search. In this case, the syntax of the function is:

<source lang="oobas">
ResultString = InStr(StartPosition, MyString, SearchString)
</source>

In the previous examples, <tt>InStr</tt> ignores uppercase and lowercase characters. To change the search so that <tt>InStr</tt> is case sensitive, add the parameter <tt>0</tt>, as shown in the following example:

<source lang="oobas">
ResultString = InStr(MyString, SearchString, 0)
</source>

Using the previous functions for editing strings, programmers can search for and replace one string in another string:

<source lang="oobas">
Function Replace(Source As String, Search As String, NewPart As String)
Dim Result As String
Dim StartPos As Long
Dim CurrentPos As Long

Result = ""
StartPos = 1
CurrentPos = 1

If Search = "" Then
Result = Source
Else
Do While CurrentPos <> 0
CurrentPos = InStr(StartPos, Source, Search)
If CurrentPos <> 0 Then
Result = Result + Mid(Source, StartPos, _
CurrentPos - StartPos)
Result = Result + NewPart
StartPos = CurrentPos + Len(Search)
Else
Result = Result + Mid(Source, StartPos, Len(Source))
End If ' Position <> 0
Loop
End If

Replace = Result
End Function
</source>

The function searches through the transferred <tt>Search</tt> string in a loop by means of <tt>InStr</tt> in the original term <tt>Source</tt>. If it finds the search term, it takes the part before the expression and writes it to the <tt>Result</tt> return buffer. It adds the <tt>NewPart</tt> section at the point of the search term <tt>Search</tt>. If no more matches are found for the search term, the function establishes the part of the string still remaining and adds this to the return buffer. It returns the string produced in this way as the result of the replacement process.

Since replacing parts of character sequences is one of the most frequently used functions, the <tt>Mid</tt> function in {{OOo}} Basic has been extended so that this task is performed automatically. The following example replaces three characters with the string <tt>is</tt> from the sixth position of the <tt>MyString</tt> string.

<source lang="oobas">
Dim MyString As String

MyString = "This was my text"
Mid(MyString, 6, 3, "is")
</source>

{{Documentation/Caution|When it is used with 4 arguments, to replace a sub-string in a string, <tt>Mid</tt> is an '''instruction''', not a function : it does not return any value !}}

== Formatting Strings ==

The <tt>Format</tt> function formats numbers as a string. To do this, the function expects a <tt>Format</tt> expression to be specified, which is then used as the template for formatting the numbers. Each place holder within the template ensures that this item is formatted correspondingly in the output value. The five most important place holders within a template are the zero (<tt>0</tt>), pound sign (<tt>#</tt>), period (<tt>.</tt>), comma (<tt>,</tt>) and dollar sign (<tt>$</tt>) characters.

The <tt>0</tt> character within the template ensures that a number is always placed at the corresponding point. If a number is not provided, 0 is displayed in its place.

A <tt>.</tt> stands for the decimal point symbol defined by the operating system in the country-specific settings.

The example below shows how the <tt>0</tt> and <tt>.</tt> characters can define the digits after the decimal point in an expression:

<source lang="oobas">
MyFormat = "0.00"
MyString = Format(-1579.8, MyFormat) ' Provides "-1579,80"
MyString = Format(1579.8, MyFormat) ' Provides "1579,80"
MyString = Format(0.4, MyFormat) ' Provides "0,40"
MyString = Format(0.434, MyFormat) ' Provides "0,43"
</source>

In the same way, zeros can be added in front of a number to achieve the desired length:

<source lang="oobas">
MyFormat = "0000.00"
MyString = Format(-1579.8, MyFormat) ' Provides "-1579,80"
MyString = Format(1579.8, MyFormat) ' Provides "1579,80"
MyString = Format(0.4, MyFormat) ' Provides "0000,40"
MyString = Format(0.434, MyFormat) ' Provides "0000,43"
</source>

A <tt>,</tt> represents the character that the operating system uses for a thousands separator, and the <tt>#</tt> stands for a digit or place that is only displayed if it is required by the input string.

<source lang="oobas">
MyFormat = "#,##0.00"
MyString = Format(-1579.8, MyFormat) ' Provides "-1.579,80"
MyString = Format(1579.8, MyFormat) ' Provides "1.579,80"
MyString = Format(0.4, MyFormat) ' Provides "0,40"
MyString = Format(0.434, MyFormat) ' Provides "0,43"
</source>

In place of the <tt>$</tt> place holder, the <tt>Format</tt> function displays the relevant currency symbol defined by the system (this example assumes a European locale has been defined):

<source lang="oobas">
MyFormat = "#,##0.00 $"
MyString = Format(-1579.8, MyFormat) ' Provides "-1.579,80 €"
MyString = Format(1579.8, MyFormat) ' Provides "1.579,80 €"
MyString = Format(0.4, MyFormat) ' Provides "0,40 €"
MyString = Format(0.434, MyFormat) ' Provides "0,43 €"
</source>

The format instructions used in VBA for formatting date and time details can also be used:

<source lang="oobas">
sub main
dim myDate as date
myDate = "01/06/98"
TestStr = Format(myDate, "mm-dd-yyyy") ' 01-06-1998
MsgBox TestStr
end sub
</source>

{{PDL1}}

@@ Line 123: / Line 123: @@
 </source>
-{{Documentation/Caution|When it is used with 4 arguments, to replace a sub-string in a string, <tt>Mid</tt> is an '''instruction''', not a function : it does not return any value !}}
+{{Caution|When it is used with 4 arguments, to replace a sub-string in a string, <tt>Mid</tt> is an '''instruction''', not a function : it does not return any value !}}
 == Formatting Strings ==

@@ Line 4: / Line 4: @@
 |ShowPrevNext=block
 |ShowPrevPage=block
-|PrevPage=EN/documentation/basic_guide/conversion_functions_(runtime_library)
+|PrevPage=EN/documentation/basic_guide/conversion_functions_runtime_library
-|NextPage=EN/documentation/basic_guide/date_and_time_(runtime_library)
+|NextPage=EN/documentation/basic_guide/date_and_time_runtime_library
 |runtime=block
 }}

← Older revision	Revision as of 16:43, 2 September 2011
(No difference)

EN/documentation/basic guide/strings runtime library - Revision history

Sancho at 10:48, 6 September 2011

Sancho at 16:50, 2 September 2011

Sancho: moved EN/documentation/basic guide/strings (runtime library) to EN/documentation/basic guide/strings runtime library

Sancho: Created page with "{{DISPLAYTITLE:Strings ({{OOo}} BASIC Runtime Library)}}{{BreadCrumbL10n}} {{Documentat..."

Sancho: Created page with "
{{DISPLAYTITLE:Strings ({{OOo}} BASIC Runtime Library)}}
{{BreadCrumbL10n}} {{Documentat..."