Sancho: Created page with "
{{DISPLAYTITLE:Loops}}
{{BreadCrumbL10n}} {{Documentation/BASICGuideTOC |ShowPrevNext=bl..."

2011-09-01T14:32:29Z

Created page with "<section begin=title /><noinclude>{{DISPLAYTITLE:</noinclude>Loops<noinclude>}}</noinclude><section end=title />{{BreadCrumbL10n}} {{Documentation/BASICGuideTOC |ShowPrevNext=bl..."

New page

<section begin=title /><noinclude>{{DISPLAYTITLE:</noinclude>Loops<noinclude>}}</noinclude><section end=title />{{BreadCrumbL10n}}

{{Documentation/BASICGuideTOC
|ShowPrevNext=block
|ShowPrevPage=block
|PrevPage=EN/documentation/basic_guide/branching
|NextPage=EN/documentation/basic_guide/procedures_and_functions
|lang=block
}}

__NOTOC__

A loop executes a code block for the number of passes that are specified. You can also have loops with an undefined number of passes.

== <tt>For...Next</tt> ==

The <tt>For...Next</tt> loop has a fixed number of passes. The loop counter defines the number of times that the loop is to be executed. In the following example, variable <tt>I</tt> is the loop counter, with an initial value of 1. The counter is incremented by 1 at the end of each pass. When variable I equals 10, the loop stops.

<source lang="oobas">
Dim I
For I = 1 To 10
' ... Inner part of loop
Next I
</source>

If you want to increment the loop counter by a value other than 1 at the end of each pass, use the <tt>Step</tt> function:

<source lang="oobas">
Dim I
For I = 1 To 10 Step 0.5
' ... Inner part of loop
Next I
</source>

In the preceding example, the counter is increased by 0.5 at the end of each pass and the loop is executed 19 times.

You can also use negative step values:

<source lang="oobas">
Dim I
For I = 10 To 1 Step -1
' ... Inner part of loop
Next I
</source>

In this example, the counter begins at 10 and is reduced by 1 at the end of each pass until the counter is 1.

The <tt>Exit For</tt> instruction allows you to exit a <tt>For</tt> loop prematurely. In the following example, the loop is terminated during the fifth pass:

<source lang="oobas">
Dim I
For I = 1 To 10
If I = 5 Then
Exit For
End If
' ... Inner part of loop
Next I
</source>

== <tt>For Each</tt> ==
The <tt>For Each...Next</tt> loop variation in VBA is supported in {{OOo}} Basic. <tt>For Each</tt> loops do not use an explicit counter like a <tt>For...Next</tt> loop does. A <tt>For Each</tt> loop says "do this to everything in this set", rather than "do this n times". For example:

<source lang="oobas">
Const d1 = 2
Const d2 = 3
Const d3 = 2
Dim i
Dim a(d1, d2, d3)
For Each i In a()
' ... Inner part of loop
Next i
</source>
The loop will execute 36 times.

== <tt>Do...Loop</tt> ==

The <tt>Do...Loop</tt> is not linked to a fixed number of passes. Instead, the <tt>Do...Loop</tt> is executed until a certain condition is met. There are four versions of the <tt>Do...Loop</tt>. In the first two examples, the code within the loop may not be executed at all ("do 0 times" logic). In the latter examples, the code will be executed at least once. (In the following examples, <tt>A > 10</tt> represents any condition):

<ol class="task">
<li>The <tt>Do While...Loop</tt> version
<source lang="oobas">
Do While A > 10
' ... loop body
Loop
</source>
checks whether the condition after the <tt>While</tt> is '''true''' before every pass and only then executes the loop.</li>
<li>The <tt>Do Until...Loop</tt> version
<source lang="oobas">
Do Until A > 10
' ... loop body
Loop
</source>
executes the loop as long as the condition after the <tt>Until</tt> evaluates to '''false'''.</li>
<li>The <tt>Do...Loop While</tt> version
<source lang="oobas">
Do
' ... loop body
Loop While A > 10
</source>
only checks the condition after the first loop pass and terminates if the condition after the <tt>While</tt> evaluates to '''false'''.</li>
<li>The <tt>Do...Loop Until</tt> version
<source lang="oobas">
Do
' ... loop body
Loop Until A > 10
</source>
also checks its condition after the first pass, but terminates if the condition after the <tt>Until</tt> evaluates to '''true'''.</li>
</ol>

As in the <tt>For...Next</tt> loop, the <tt>Do...Loop</tt> also provides a terminate command. The <tt>Exit Do</tt> command can exit at loop at any point within the loop.

<source lang="oobas">
Do
If A = 4 Then
Exit Do
End If
' ... loop body
Loop While A > 10
</source>
In some cases the loop may only terminate when a condition is met within the loop. Then you can use the "perpetual" Do Loop:

<source lang="oobas">
Do
' ... some internal calculations
If A = 4 Then Exit Do
' ... other instructions
Loop
</source>

== <tt>While...Wend</tt> ==

The <tt>While...Wend</tt> loop construct works exactly the same as the <tt>Do While...Loop</tt>, but with the disadvantage that there is no <tt>Exit</tt> command available. The following two loops produce identical results:

<source lang="oobas">
Do While A > 10
' ... loop body
Loop

While A > 10
' ... loop body
Wend
</source>

== Programming Example: Sorting With Embedded Loops ==

There are many ways to use loops, for example, to search lists, return values, or execute complex mathematical tasks. The following example is an algorithm that uses two loops to sort a list by names.

<source lang="oobas">
Sub Sort
Dim Entry(1 To 10) As String
Dim Count As Integer
Dim Count2 As Integer
Dim Temp As String

Entry(1) = "Patty"
Entry(2) = "Kurt"
Entry(3) = "Thomas"
Entry(4) = "Michael"
Entry(5) = "David"
Entry(6) = "Cathy"
Entry(7) = "Susie"
Entry(8) = "Edward"
Entry(9) = "Christine"
Entry(10) = "Jerry"

For Count = 1 To 9
For Count2 = Count + 1 To 10
If Entry(Count) > Entry(Count2) Then
Temp = Entry(Count)
Entry(Count) = Entry(Count2)
Entry(Count2) = Temp
End If
Next Count2
Next Count

For Count = 1 To 10
Print Entry(Count)
Next Count

End Sub
</source>

The values are interchanged as pairs several times until they are finally sorted in ascending order. Like bubbles, the variables gradually migrate to the right position. For this reason, this algorithm is also known as a [http://en.wikipedia.org/wiki/Bubble_sort Bubble Sort].

{{PDL1}}

EN/documentation/basic guide/loops - Revision history

Sancho: Created page with "{{DISPLAYTITLE:Loops}}{{BreadCrumbL10n}} {{Documentation/BASICGuideTOC |ShowPrevNext=bl..."

Sancho: Created page with "
{{DISPLAYTITLE:Loops}}
{{BreadCrumbL10n}} {{Documentation/BASICGuideTOC |ShowPrevNext=bl..."