Sancho: Основной текст

2011-09-02T18:15:16Z

Основной текст

New page

<section begin=title /><noinclude>{{DISPLAYTITLE:</noinclude>Formatting Spreadsheet Documents<noinclude>}}</noinclude><section end=title />{{BreadCrumbL10n}}

{{Documentation/BASICGuideTOC
|ShowPrevNext=block
|ShowPrevPage=block
|PrevPage=EN/documentation/basic_guide/cells_and_ranges
|NextPage=EN/documentation/basic_guide/editing_spreadsheet_documents
|spread=block
}}

__NOTOC__

A spreadsheet document provides properties and methods for formatting cells and pages.

== Cell Properties ==

There are numerous options for formatting cells, such as specifying the font type and size for text. Each cell supports the <idl>com.sun.star.style.CharacterProperties</idl> and <idl>com.sun.star.style.ParagraphProperties</idl> services, the main properties of which are described in [[Documentation/BASIC Guide/Text Documents|Text Documents]]. Special cell formatting is handled by the <idl>com.sun.star.table.CellProperties</idl> service. The main properties of this service are described in the following sections.

You can apply all of the named properties to individual cells and to cell ranges.

{{VBAnote|The <tt>CellProperties</tt> object in the {{OOo}} API is comparable with the <tt>Interior</tt> object from VBA which also defines cell-specific properties.}}

== Background Color and Shadows ==

The <idl>com.sun.star.table.CellProperties</idl> service provides the following properties for defining background colors and shadows:

;<tt>CellBackColor (Long)</tt>:background color of the table cell
;<tt>IsCellBackgroundTransparent (Boolean)</tt>:sets the background color to transparent
;<tt>ShadowFormat (struct)</tt>:specifies the shadow for cells (structure in accordance with <idl>com.sun.star.table.ShadowFormat</idl>)

The <idl>com.sun.star.table.ShadowFormat</idl> structure and the detailed specifications for cell shadows have the following structure:

;<tt>Location (enum)</tt>:position of shadow (value from the <idl>com.sun.star.table.ShadowLocation</idl> structure).
;<tt>ShadowWidth (Short)</tt>:size of shadow in hundredths of a millimeter
;<tt>IsTransparent (Boolean)</tt>:sets the shadow to transparent
;<tt>Color (Long)</tt>:color of shadow

The following example writes the number 1000 to the B2 cell, changes the background color to red using the <tt>CellBackColor</tt> property, and then creates a light gray shadow for the cell that is moved 1 mm to the left and down.

<source lang="oobas">
Dim Doc As Object
Dim Sheet As Object
Dim Cell As Object
Dim ShadowFormat As New com.sun.star.table.ShadowFormat

Doc = ThisComponent
Sheet = Doc.Sheets(0)
Cell = Sheet.getCellByPosition(1,1)

Cell.Value = 1000

Cell.CellBackColor = RGB(255, 0, 0)

ShadowFormat.Location = com.sun.star.table.ShadowLocation.BOTTOM_RIGHT
ShadowFormat.ShadowWidth = 100
ShadowFormat.Color = RGB(160, 160, 160)

Cell.ShadowFormat = ShadowFormat
</source>

== Justification ==

{{OOo}} provides various functions that allow you to change the justification of a text in a table cell.

The following properties define the horizontal and vertical justification of a text:

;<tt>HoriJustify (enum)</tt>:horizontal justification of the text (value from <idl>com.sun.star.table.CellHoriJustify</idl>)
;<tt>VertJustify (enum)</tt>:vertical justification of the text (value from <idl>com.sun.star.table.CellVertJustify</idl>)
;<tt>Orientation (enum)</tt>:orientation of text (value in accordance with <idl>com.sun.star.table.CellOrientation</idl>)
;<tt>IsTextWrapped (Boolean)</tt>:permits automatic line breaks within the cell
;<tt>RotateAngle (Long)</tt>:angle of rotation of text in hundredths of a degree

The following example shows how you can "stack" the contents of a cell so that the individual characters are printed one under another in the top left corner of the cell. The characters are not rotated.

<source lang="oobas">
Dim Doc As Object
Dim Sheet As Object
Dim Cell As Object

Doc = ThisComponent
Sheet = Doc.Sheets(0)
Cell = Sheet.getCellByPosition(1,1)

Cell.Value = 1000

Cell.HoriJustify = com.sun.star.table.CellHoriJustify.LEFT
Cell.VertJustify = com.sun.star.table.CellVertJustify.TOP
Cell.Orientation = com.sun.star.table.CellOrientation.STACKED
</source>

== Number, Date and Text Format ==

{{OOo}} provides a whole range of predefined date and time formats. Each of these formats has an internal number that is used to assign the format to cells using the <tt>NumberFormat</tt> property. {{OOo}} provides the <tt>queryKey</tt> and <tt>addNew</tt> methods so that you can access existing number formats as well as create your own number formats. The methods are accessed through the following object call:

<source lang="oobas">
NumberFormats = Doc.NumberFormats
</source>

A format is specified using a format string that is structured in a similar way to the format function of {{OOo}} Basic. However there is one major difference: whereas the command format expects English abbreviations and decimal points or characters as thousands separators, the country-specified abbreviations must be used for the structure of a command format for the <tt>NumberFormats</tt> object.

The following example formats the B2 cell so that numbers are displayed with three decimal places and use commas as a thousands separator.

<source lang="oobas">
Dim Doc As Object
Dim Sheet As Object
Dim Cell As Object
Dim NumberFormats As Object
Dim NumberFormatString As String
Dim NumberFormatId As Long
Dim LocalSettings As New com.sun.star.lang.Locale

Doc = ThisComponent
Sheet = Doc.Sheets(0)
Cell = Sheet.getCellByPosition(1,1)

Cell.Value = 23400.3523565

LocalSettings.Language = "en"
LocalSettings.Country = "us"

NumberFormats = Doc.NumberFormats
NumberFormatString = "#,##0.000"

NumberFormatId = NumberFormats.queryKey(NumberFormatString, LocalSettings, True)
If NumberFormatId = -1 Then
NumberFormatId = NumberFormats.addNew(NumberFormatString, LocalSettings)
End If

MsgBox NumberFormatId
Cell.NumberFormat = NumberFormatId
</source>

The '''Format Cells''' dialog in {{OOo}} Calc provides an overview of the different formatting options for cells.

== Page Properties ==

Page properties are the formatting options that position document content on a page as well as visual elements that are repeated page after page. These include

* Paper formats
* Page margins
* Headers and footers.

The procedure for defining page formats differs from other forms of formatting. Whereas cell, paragraph, and character elements can be formatted directly, page formats can also be defined and indirectly applied using page styles. For example, headers or footers are added to the page style.

The following sections describe the main formatting options for spreadsheet pages. Many of the styles that are described are also available for text documents. The page properties that are valid for both types of documents are defined in the <idl>com.sun.star.style.PageProperties</idl> service. The page properties that only apply to spreadsheet documents are defined in the <idl>com.sun.star.sheet.TablePageStyle</idl> service.

{{VBAnote|The page properties (page margins, borders, and so on) for a Microsoft Office document are defined by means of a <tt>PageSetup</tt> object at the <tt>Worksheet</tt> object (Excel) or <tt>Document</tt> object (Word) level. In {{OOo}}, these properties are defined using a page style which in turn is linked to the associated document.}}

== Page Background ==

The <idl>com.sun.star.style.PageProperties</idl> service defines the following properties of a pages background:

;<tt>BackColor (long)</tt>:color of background
;<tt>BackGraphicURL (String)</tt>:URL of the background graphics that you want to use
;<tt>BackGraphicFilter (String)</tt>:name of the filter for interpreting the background graphics
;<tt>BackGraphicLocation (Enum)</tt>:position of the background graphics (value according to enumeration)
;<tt>BackTransparent (Boolean)</tt>:makes the background transparent

== Page Format ==

The page format is defined using the following properties of the <idl>com.sun.star.style.PageProperties</idl> service:

;<tt>IsLandscape (Boolean)</tt>:landscape format
;<tt>Width (long)</tt>:width of page in hundredths of a millimeter
;<tt>Height (long)</tt>:height of page in hundredths of a millimeter
;<tt>PrinterPaperTray (String)</tt>:name of the printer paper tray that you want to use

The following example sets the page size of the "Default" page style to the DIN A5 landscape format (height 14.8 cm, width 21 cm):

<source lang="oobas">
Dim Doc As Object
Dim Sheet As Object
Dim StyleFamilies As Object
Dim PageStyles As Object
Dim DefPage As Object

Doc = ThisComponent
StyleFamilies = Doc.StyleFamilies
PageStyles = StyleFamilies.getByName("PageStyles")
DefPage = PageStyles.getByName("Default")

DefPage.IsLandscape = True
DefPage.Width = 21000
DefPage.Height = 14800
</source>

== Page Margin, Border, and Shadow ==

The <idl>com.sun.star.style.PageProperties</idl> service provides the following properties for adjusting page margins as well as borders and shadows:

;<tt>LeftMargin (long)</tt>:width of the left hand page margin in hundredths of a millimeter
;<tt>RightMargin (long)</tt>:width of the right hand page margin in hundredths of a millimeter
;<tt>TopMargin (long)</tt>:width of the top page margin in hundredths of a millimeter
;<tt>BottomMargin (long)</tt>:width of the bottom page margin in hundredths of a millimeter
;<tt>LeftBorder (struct)</tt>:specifications for left-hand line of page border (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>RightBorder (struct)</tt>:specifications for right-hand line of page border (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>TopBorder (struct)</tt>:specifications for top line of page border (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>BottomBorder (struct)</tt>:specifications for bottom line of page border (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>LeftBorderDistance (long)</tt>:distance between left-hand page border and page content in hundredths of a millimeter
;<tt>RightBorderDistance (long)</tt>:distance between right-hand page border and page content in hundredths of a millimeter
;<tt>TopBorderDistance (long)</tt>:distance between top page border and page content in hundredths of a millimeter
;<tt>BottomBorderDistance (long)</tt>:distance between bottom page border and page content in hundredths of a millimeter
;<tt>ShadowFormat (struct)</tt>:specifications for shadow of content area of page (<idl>com.sun.star.table.ShadowFormat</idl> structure)

The following example sets the left and right-hand borders of the "Default" page style to 1 centimeter.

<source lang="oobas">
Dim Doc As Object
Dim Sheet As Object
Dim StyleFamilies As Object
Dim PageStyles As Object
Dim DefPage As Object

Doc = ThisComponent
StyleFamilies = Doc.StyleFamilies
PageStyles = StyleFamilies.getByName("PageStyles")
DefPage = PageStyles.getByName("Default")

DefPage.LeftMargin = 1000
DefPage.RightMargin = 1000
</source>

== Headers and Footers ==

The headers and footers of a document form part of the page properties and are defined using the <idl>com.sun.star.style.PageProperties</idl> service. The properties for formatting headers are:

;<tt>HeaderIsOn (Boolean)</tt>:header is activated
;<tt>HeaderLeftMargin (long)</tt>:distance between header and left-hand page margin in hundredths of a millimeter
;<tt>HeaderRightMargin (long)</tt>:distance between header and right-hand page margin in hundredths of a millimeter
;<tt>HeaderBodyDistance (long)</tt>:distance between header and main body of document in hundredths of a millimeter
;<tt>HeaderHeight (long)</tt>:height of header in hundredths of a millimeter
;<tt>HeaderIsDynamicHeight (Boolean)</tt>:height of header is automatically adapted to content
;<tt>HeaderLeftBorder (struct)</tt>:details of the left-hand border of frame around header (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>HeaderRightBorder (struct)</tt>:details of the right-hand border of frame around header (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>HeaderTopBorder (struct)</tt>:details of the top line of the border around header (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>HeaderBottomBorder (struct)</tt>:details of the bottom line of the border around header (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>HeaderLeftBorderDistance (long)</tt>:distance between left-hand border and content of header in hundredths of a millimeter
;<tt>HeaderRightBorderDistance (long)</tt>:distance between right-hand border and content of header in hundredths of a millimeter
;<tt>HeaderTopBorderDistance (long)</tt>:distance between top border and content of header in hundredths of a millimeter
;<tt>HeaderBottomBorderDistance (long)</tt>:distance between bottom border and content of header in hundredths of a millimeter
;<tt>HeaderIsShared (Boolean)</tt>:headers on even and odd pages have the same content (refer to <tt>HeaderText</tt> , <tt>HeaderTextLeft</tt>, and <tt>HeaderTextRight</tt> )
;<tt>HeaderBackColor (long)</tt>:background color of header
;<tt>HeaderBackGraphicURL (String)</tt>:URL of the background graphics that you want to use
;<tt>HeaderBackGraphicFilter (String)</tt>:name of the filter for interpreting the background graphics for the header
;<tt>HeaderBackGraphicLocation (Enum)</tt>:position of the background graphics for the header (value according to <idl>com.sun.star.style.GraphicLocation</idl> enumeration)
;<tt>HeaderBackTransparent (Boolean)</tt>:shows the background of the header as transparent
;<tt>HeaderShadowFormat (struct)</tt>:details of shadow of header (<idl>com.sun.star.table.ShadowFormat</idl> structure)

The properties for formatting footers are:

;<tt>FooterIsOn (Boolean)</tt>:footer is activated
;<tt>FooterLeftMargin (long)</tt>:distance between footer and left-hand page margin in hundredths of a millimeter
;<tt>FooterRightMargin (long)</tt>:distance between footer and right-hand page margin in hundredths of a millimeter
;<tt>FooterBodyDistance (long)</tt>:distance between footer and main body of document in hundredths of a millimeter
;<tt>FooterHeight (long)</tt>:height of footer in hundredths of a millimeter
;<tt>FooterIsDynamicHeight (Boolean)</tt>:height of footer is adapted automatically to the content
;<tt>FooterLeftBorder (struct)</tt>:details of left-hand line of border around footer (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>FooterRightBorder (struct)</tt>:details of right-hand line of border around footer (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>FooterTopBorder (struct)</tt>:details of top line of border around footer (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>FooterBottomBorder (struct)</tt>:details of bottom line of border around footer (<idl>com.sun.star.table.BorderLine</idl> structure)
;<tt>FooterLeftBorderDistance (long)</tt>:distance between left-hand border and content of footer in hundredths of a millimeter
;<tt>FooterRightBorderDistance (long)</tt>:distance between right-hand border and content of footer in hundredths of a millimeter
;<tt>FooterTopBorderDistance (long)</tt>:distance between top border and content of footer in hundredths of a millimeter
;<tt>FooterBottomBorderDistance (long)</tt>:distance between bottom border and content of footer in hundredths of a millimeter
;<tt>FooterIsShared (Boolean)</tt>:the footers on the even and odd pages have the same content (refer to <tt>FooterText</tt>, <tt>FooterTextLeft</tt>, and <tt>FooterTextRight</tt> )
;<tt>FooterBackColor (long)</tt>:background color of footer
;<tt>FooterBackGraphicURL (String)</tt>:URL of the background graphics that you want to use
;<tt>FooterBackGraphicFilter (String)</tt>:name of the filter for interpreting the background graphics for the footer
;<tt>FooterBackGraphicLocation (Enum)</tt>:position of background graphics for the footer (value according to <idl>com.sun.star.style.GraphicLocation</idl> enumeration)
;<tt>FooterBackTransparent (Boolean) </tt>:shows the background of the footer as transparent
;<tt>FooterShadowFormat (struct)</tt>:details of shadow of footer (<idl>com.sun.star.table.ShadowFormat</idl> structure)

== Changing the Text of Headers and Footers ==

The content of headers and footers in a spreadsheet is accessed through the following properties:

;<tt>LeftPageHeaderContent (Object)</tt>:content of headers for even pages (<idl>com.sun.star.sheet.HeaderFooterContent</idl> service)
;<tt>RightPageHeaderContent (Object)</tt>:content of headers for odd pages (<idl>com.sun.star.sheet.HeaderFooterContent</idl> service)
;<tt>LeftPageFooterContent (Object)</tt>:content of footers for even pages (<idl>com.sun.star.sheet.HeaderFooterContent</idl> service)
;<tt>RightPageFooterContent (Object)</tt>:content of footers for odd pages (<idl>com.sun.star.sheet.HeaderFooterContent</idl> service)

If you do not need to distinguish between headers or footers for odd and even pages (the <tt>FooterIsShared</tt> property is <tt>False</tt>), then set the properties for headers and footers on odd pages.

All the named objects return an object that supports the <idl>com.sun.star.sheet.HeaderFooterContent</idl> service. By means of the (non-genuine) properties <tt>LeftText</tt>, <tt>CenterText</tt>, and <tt>RightText</tt>, this service provides three text elements for the headers and footers of {{OOo}} Calc.

The following example writes the "Just a Test." value in the left-hand text field of the header from the "Default" template.

<source lang="oobas">
Dim Doc As Object
Dim Sheet As Object
Dim StyleFamilies As Object
Dim PageStyles As Object
Dim DefPage As Object
Dim HText As Object
Dim HContent As Object
Doc = ThisComponent
StyleFamilies = Doc.StyleFamilies
PageStyles = StyleFamilies.getByName("PageStyles")
DefPage = PageStyles.getByName("Default")

DefPage.HeaderIsOn = True
HContent = DefPage.RightPageHeaderContent
HText = HContent.LeftText
HText.String = "Just a Test."
DefPage.RightPageHeaderContent = HContent
</source>

Note the last line in the example: Once the text is changed, the <tt>TextContent</tt> object must be assigned to the header again so that the change is effective.

Another mechanism for changing the text of headers and footers is available for text documents ({{OOo}} Writer) because these consist of a single block of text. The following properties are defined in the <idl>com.sun.star.style.PageProperties</idl> service:

;<tt>HeaderText (Object) </tt>:text object with content of the header (<idl>com.sun.star.text.XText</idl> service)
;<tt>HeaderTextLeft (Object)</tt>:text object with content of headers on left-hand pages (<idl>com.sun.star.text.XText</idl> service)
;<tt>HeaderTextRight (Object)</tt>:text object with content of headers on right-hand pages (<idl>com.sun.star.text.XText</idl> service)
;<tt>FooterText (Object)</tt>:text object with content of the footer (<idl>com.sun.star.text.XText</idl> service)
;<tt>FooterTextLeft (Object)</tt>:text object with content of footers on left-hand pages (<idl>com.sun.star.text.XText</idl> service)
;<tt>FooterTextRight (Object)</tt>:text object with content of footers on right-hand pages (<idl>com.sun.star.text.XText</idl> service)

The following example creates a header in the "Default" page style for text documents and adds the text "Just a Test" to the header.

<source lang="oobas">
Dim Doc As Object
Dim Sheet As Object
Dim StyleFamilies As Object
Dim PageStyles As Object
Dim DefPage As Object
Dim HText As Object

Doc = ThisComponent
StyleFamilies = Doc.StyleFamilies
PageStyles = StyleFamilies.getByName("PageStyles")
DefPage = PageStyles.getByName("Default")

DefPage.HeaderIsOn = True
HText = DefPage.HeaderText

HText.String = "Just a Test."
</source>

In this instance, access is provided directly through the <tt>HeaderText</tt> property of the page style rather than the <tt>HeaderFooterContent</tt> object.

== Centering (Spreadsheets Only) ==

The <idl>com.sun.star.sheet.TablePageStyle</idl> service is only used in {{OOo}} Calc page styles and allows cell ranges that you want printed to be centered on the page. This service provides the following properties:

;<tt>CenterHorizontally (Boolean)</tt>:table content is centered horizontally
;<tt>CenterVertically (Boolean)</tt>:table content is centered vertically

== Definition of Elements to be Printed (Spreadsheets Only) ==

When you format sheets, you can define whether page elements are visible. For this purpose, the <idl>com.sun.star.sheet.TablePageStyle</idl> service provides the following properties:

;<tt>PrintAnnotations (Boolean)</tt>:prints cell comments
;<tt>PrintGrid (Boolean)</tt>:prints the cell gridlines
;<tt>PrintHeaders (Boolean)</tt>:prints the row and column headings
;<tt>PrintCharts (Boolean)</tt>:prints charts contained in a sheet
;<tt>PrintObjects (Boolean)</tt>:prints embedded objects
;<tt>PrintDrawing (Boolean)</tt>:prints draw objects
;<tt>PrintDownFirst (Boolean)</tt>:if the contents of a sheet extend across several pages, they are first printed in vertically descending order, and then down the right-hand side.
;<tt>PrintFormulas (Boolean)</tt>:prints the formulas instead of the calculated values
;<tt>PrintZeroValues (Boolean)</tt>:prints the zero values

{{PDL1}}

EN/documentation/basic guide/formatting spreadsheet documents - Revision history

Sancho: Основной текст