Sancho: Created page with "
{{DISPLAYTITLE:Arrays}}
{{BreadCrumbL10n}} {{Documentation/BASICGuideTOC |ShowPrevNext=..."

2011-09-01T14:10:21Z

Created page with "<section begin=title /><noinclude>{{DISPLAYTITLE:</noinclude>Arrays<noinclude>}}</noinclude><section end=title />{{BreadCrumbL10n}} {{Documentation/BASICGuideTOC |ShowPrevNext=..."

New page

<section begin=title /><noinclude>{{DISPLAYTITLE:</noinclude>Arrays<noinclude>}}</noinclude><section end=title />{{BreadCrumbL10n}}

{{Documentation/BASICGuideTOC
|ShowPrevNext=block
|ShowPrevPage=block
|PrevPage=EN/documentation/basic_guide/date
|NextPage=EN/documentation/basic_guide/scope_of_variables
|lang=block
}}

__NOTOC__
In addition to simple variables (scalars), {{OOo}} Basic also supports arrays (data fields). A data field contains several variables, which are addressed through an index.

= Defining Arrays =
Arrays can be defined as follows:

==Simple Arrays==

An array declaration is similar to that of a simple variable declaration. However, unlike the variable declaration, the array name is followed by parentheses which contain the specifications for the number of elements. The expression

<source lang="oobas">
Dim MyArray(3)
</source>

declares an array that has four variables of the variant data type, namely <tt>MyArray(0)</tt>, <tt>MyArray(1)</tt>, <tt>MyArray(2)</tt>, and <tt>MyArray(3)</tt>.

You can also declare type-specific variables in an array. For example, the following line declares an array with four integer variables:

<source lang="oobas">
Dim MyInteger(3) As Integer
</source>

In the previous examples, the index for the array always begins with the standard start value of zero. As an alternative, a validity range with start and end values can be specified for the data field declaration. The following example declares a data field that has six integer values and which can be addressed using the indexes 5 to 10:

<source lang="oobas">
Dim MyInteger(5 To 10) As Integer
</source>

The indexes do not need to be positive values. The following example also shows a correct declaration, but with negative data field limits:

<source lang="oobas">
Dim MyInteger(-10 To -5) As Integer
</source>

It declares an integer data field with 6 values that can be addressed using the indexes -10 to -5.

There are no practical limits on the indexes or on the number of elements in an array, so long as there is enough memory:

<source lang="oobas">
Dim s(-53000 to 89000) As String
s(-52000) = "aa"
s(79999) = "bb"
print s(-52000), s(79999)
</source>

{{VBAnote|Other limit values sometimes apply for data field indexes in VBA. The same also applies to the maximum number of elements possible per dimension. The values valid there can be found in the relevant VBA documentation.}}

==Specified Value for Start Index==

The start index of a data field usually begins with the value 0. Alternatively, you can change the start index for all data field declarations to the value 1 by using the call:

<source lang="oobas">
Option Base 1
</source>

The call must be included in the header of a module if you want it to apply to all array declarations in the module. However, this call does not affect the UNO sequences that are defined through the {{OOo}} API whose index always begins with 0. To improve clarity, you should avoid using Option Base 1.

The number of elements in an array is not affected if you use <tt>Option Base 1</tt>, only the start index changes. The declaration

<source lang="oobas">
Option Base 1
' ...
Dim MyInteger(3)
</source>

creates 4 integer variables which can be described with the expressions <tt>MyInteger(1)</tt>, <tt>MyInteger(2)</tt>, <tt>MyInteger(3)</tt>, and <tt>MyInteger(4)</tt>.

{{VBAnote|In {{OOo}} Basic, the expression <tt>Option Base 1</tt> does not affect the number of elements in an array as it does in VBA. It is, rather, the start index which moves in {{OOo}} Basic. While the declaration <tt>MyInteger(3)</tt> creates three integer values in VBA with the indexes 1 to 3, the same declaration in {{OOo}} Basic creates four integer values with the indexes 1 to 4. By using <tt>Option Compatible</tt>, {{OOo}} Basic behaves like VBA.}}

==Multi-Dimensional Data Fields==

In addition to single dimensional data fields, {{OOo}} Basic also supports work with multi-dimensional data fields. The corresponding dimensions are separated from one another by commas. The example

<source lang="oobas">
Dim MyIntArray(5, 5) As Integer
</source>

defines an integer array with two dimensions, each with 6 indexes (can be addressed through the indexes 0 to 5). The entire array can record a total of 6 x 6 = 36 integer values.

You can define hundreds of dimensions in {{OOo}} Basic Arrays; however, the amount of available memory limits the number of dimensions you can have.

==Dynamic Changes in the Dimensions of Data Fields==

The previous examples are based on data fields of a specified dimension. You can also define arrays in which the dimension of the data fields dynamically changes. For example, you can define an array to contain all of the words in a text that begin with the letter A. As the number of these words is initially unknown, you need to be able to subsequently change the field limits. To do this in {{OOo}} Basic, use the following call:

<source lang="oobas">
ReDim MyArray(10)
</source>

{{VBAnote|Unlike VBA, where you can only dimension dynamic arrays by using <tt>Dim MyArray()</tt>, {{OOo}} Basic lets you change both static and dynamic arrays using <tt>ReDim</tt>.}}

The following example changes the dimension of the initial array so that it can record 11 or 21 values:

<source lang="oobas">
Dim MyArray(4) As Integer ' Declaration with five elements
' ...
ReDim MyArray(10) As Integer ' Increase to 11 elements
' ...
ReDim MyArray(20) As Integer ' Increase to 21 elements
</source>

When you reset the dimensions of an array, you can use any of the options outlined in the previous sections. This includes declaring multi-dimensional data fields and specifying explicit start and end values. When the dimensions of the data field are changed, all contents are lost. If you want to keep the original values, use the <tt>Preserve</tt> command:

<source lang="oobas">
Dim MyArray(10) As Integer ' Defining the initial
' dimensions
' ...
ReDim Preserve MyArray(20) As Integer ' Increase in
' data field, while
' retaining content
</source>

When you use <tt>Preserve</tt>, ensure that the number of dimensions and the type of variables remain the same.

{{VBAnote|Unlike VBA, where only the upper limit of the last dimension of a data field can be changed through <tt>Preserve</tt>, {{OOo}} Basic lets you change other dimensions as well.}}

If you use <tt>ReDim</tt> with <tt>Preserve</tt>, you must use the same data type as specified in the original data field declaration.

==Determining the Dimensions of Data Fields==

Functions LBound() and UBound() return respectively the lowest permitted index value and the highest permitted index value of an array. This is useful when an array has changed its dimensions.

<source lang="oobas">
Dim MyArray(10) As Integer
' ... some instructions
Dim n As Integer
n = 47 ' could be the result of a computation
Redim MyArray(n) As Integer
MsgBox(LBound(MyArray)) ' displays : 0
MsgBox(UBound(MyArray)) ' displays : 47
</source>

For a multi-dimensional array you need to specify the position (1 to n) of the index you want to know the permitted lower and upper values:

<source lang="oobas">
Dim MyArray(10, 13 to 28) As Integer
MsgBox(LBound(MyArray, 2)) ' displays : 13
MsgBox(UBound(MyArray, 2)) ' displays : 28
</source>

==Empty arrays==

In some cases, especially when dealing with the API, you need to declare an empty array. Such array is declared without dimension, but may later be filled by an API function or with a Redim statement:

<source lang="oobas">
Dim s() As String ' declare an empty array
' --- later in the program ...
Redim s(13) As String
</source>

You cannot assign a value to an empty array, since it does not contain any elements.

The "signature" of an empty array is that UBound() returns -1 and LBound() returns 0:

<source lang="oobas">
Dim MyArray() As Integer
MsgBox(LBound(MyArray)) ' displays : 0
MsgBox(UBound(MyArray)) ' displays : -1
</source>

Some API functions return an array containing elements (indexed from zero) or return an empty array. Use UBound() to check if the returned array is empty.

= Defining values for arrays =

Values for the Array fields can be stored like this:

MyArray(0) = "somevalue"

= Accessing Arrays =

Accessing values in an array works like this:

MsgBox("Value:" & MyArray(0))

= Array Creation, value assignment and access example =
And example containing all steps that show real array usage:

Sub TestArrayAxess
Dim MyArray(3)
MyArray(0) = "lala"
MsgBox("Value:" & MyArray(0))
End Sub

{{PDL1}}

EN/documentation/basic guide/arrays - Revision history

Sancho: Created page with "{{DISPLAYTITLE:Arrays}}{{BreadCrumbL10n}} {{Documentation/BASICGuideTOC |ShowPrevNext=..."

Sancho: Created page with "
{{DISPLAYTITLE:Arrays}}
{{BreadCrumbL10n}} {{Documentation/BASICGuideTOC |ShowPrevNext=..."